Cannot Use FrontPage Bots with shared SSL

FrontPage Web Bots will only work in the IIS Virtual folder to which it is published. Therefore, any forms on your site that use a FrontPage bot to save results, send email, etc., will not work from your shared SSL location, as it works as a separate virtual directory on a different IIS site. If you absolutely must use a FrontPage Bot for your form submission, then you will need to obtain am SSL certificate for your site. Otherwise, you can process the form using another method, such as an ASP or Perl script.
Below is a script you can use to switch your form from using a FrontPage Bot to ASP. To use it, copy the code below into notepad and save the file as 'writeresults.asp'. Save the file to a location in your website. Then open your form in notepad and locate the line : <Form Method="Post".... >"
Modify this line to read:
"<Form Method="Post" Action="http://www.domain.com/folder/writeresults.asp" Name="Processing Form">"
Where "domain.com" is your site's domain name and "folder" is the name of the folder where the writeresults.asp script is located.

Here is the script. It will need to be modified according to the top instructions to suit your site.

<%

'******************************************************************************

'Post to this page from your frontpage form
'You will need to configure the following:

'saveto - The complete absolute path to the file where form results will be saved
' (blank if not used)
'redirectpath - The page URL to redirect to after the person clicks submit on your form.
' Do not specify a relative path, only a full path with "http://"
' (if left blank, then a generic plain-text conformation page will appear)
'txtfileoremail - If 0 then form results are saved to a text file
' If 1 then form results are e-mailed to a specified address
' If 2 then both
'emailtoaddress - If e-mailing results, specify source e-mail address here, otherwise blank
'emailfromaddress - If e-mailing results, specify destination e-mail address here,
' otherwise blank


'For example:
'saveto = "d:\inetpub\sitename\_private\form_results.txt"
'redirect = "http://www.sitename.com/confirmation/confirmation.htm"
'txtfileoremail = 2
'emailtoaddress = "support@sitename.com"
'emailfromaddress = "test@test.com"

'******************************************************************************


saveto = "d:\inetpub\domain\testorder\form_results.txt"
redirectpath = "http://www.domain.com/testorder/order_form_thanks.htm"
txtfileoremail = 1
emailtoaddress = "Recipient@domain.com"
emailfromaddress = "Sender@domain.com"

if txtfileoremail = 0 or txtfileoremail = 2 then

set fso = Server.CreateObject("Scripting.FileSystemObject")

if (fso.FileExists(saveto)) then
Set tf = fso.OpenTextFile(saveto, 8, True)
else
set tf = fso.CreateTextFile(saveto)
end if

For each inputField in Request.Form
For each inputValue in Request.Form(inputField)
tf.writeline(inputfield & " = " & inputValue)
Next
Next

IP = Request.ServerVariables("REMOTE_ADDR")
tf.writeline("IP = " & IP)
tf.writeline("Date/Time = " & date & " " & time)
tf.writeline("")
tf.writeline("********************************************")
tf.writeline("")
tf.close

set tf = nothing
set fso = nothing

end if

if txtfileoremail = 1 or txtfileoremail = 2 then

For each inputField in Request.Form
For each inputValue in Request.Form(inputField)
msg = msg & inputfield & " = " & inputValue & "<BR>"
Next
Next

IP = Request.ServerVariables("REMOTE_ADDR")
msg = msg & "IP = " & IP

Dim myMail
Set myMail = Server.CreateObject("CDONTS.NewMail")
myMail.From = emailfromaddress
myMail.To = emailtoaddress
myMail.Subject = "Form Results"
myMail.BodyFormat = 0
myMail.MailFormat = 0
myMail.Body = msg
myMail.Send

set myMail = nothing

end if

if redirectpath <> "" then
response.redirect redirectpath
else

response.write "<FONT FACE=ARIAL SIZE=4>Form Confirmation - Thanks for your submission.</FONT><BR><BR>"

For each inputField in Request.Form
For each inputValue in Request.Form(inputField)
response.write inputfield & " = " & inputValue & "<BR>"
Next
Next

end if

%>

Add Feedback